# $Id: PKGBUILD 60156 2009-12-01 10:21:15Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: mosra <mosra@centrum.cz>

pkgname=kdelibs
pkgver=4.5.1
pkgrel=2
pkgdesc="KDE Core Libraries"
arch=('i686' 'x86_64')
url='http://www.kde.org'
license=('GPL' 'LGPL' 'FDL')
depends=('shared-mime-info' 'hal' 'xz' 'enchant' 'jasper' 'openexr' 'giflib'
         'strigi' 'libxtst' 'soprano' 'ca-certificates' 'xdg-utils' 'qca' 'polkit-qt'
         'libxss' 'phonon' 'shared-desktop-ontologies' 'attica' 'libxcursor' 'libdbusmenu-qt'
	 'hicolor-icon-theme')
makedepends=('pkgconfig' 'cmake' 'automoc4' 'intltool' 'avahi' 'libgl' 'hspell' 'docbook-xsl')
replaces=('arts' 'kdelibs-experimental')
install='kdelibs.install'
source=("http://download.kde.org/stable/${pkgver}/src/${pkgname}-${pkgver}.tar.bz2"
        'kde-applications-menu.patch' 'archlinux-menu.patch' 'abs-syntax-highlight.patch'
        'katetexthistory.cpp.patch' 'katetexthistory.h.patch' 'katetextblock.cpp.patch')
sha1sums=('9d3eff7c35040bba6b6345a41e98a8e29ed2a1a3'
          '86ee8c8660f19de8141ac99cd6943964d97a1ed7'
          '63a850ab4196b9d06934f2b4a13acd9f7739bc67'
          'd994f262356af5b9e4e9619646e471bd98c91efb'
          '7426650129602efb2b08b04c74fc22130ce48f25'
          '3b00a7c62189a317c141242a10e917e9ff58613b'
          'f512e61c7c32e0ea9c26f24c36d9c2fc03fbee89')

build() {
       cd ${srcdir}/${pkgname}-${pkgver}

       # avoid file conflict with gnome-menu
       patch -p1 -i $srcdir/kde-applications-menu.patch
       # add Archlinux menu entry
       patch -p1 -i $srcdir/archlinux-menu.patch
       # add syntax highlightning for PKGBUILD and .install files
       patch -p1 -i $srcdir/abs-syntax-highlight.patch

       # Patched Kate to work with new KDevelop
       patch -p4 -i $srcdir/katetexthistory.cpp.patch
       patch -p4 -i $srcdir/katetexthistory.h.patch
       patch -p4 -i $srcdir/katetextblock.cpp.patch

       cd ${srcdir}
       mkdir -p build
       cd build
       cmake ../${pkgname}-${pkgver} \
               -DCMAKE_BUILD_TYPE=Release \
               -DCMAKE_SKIP_RPATH=ON \
               -DKDE_DISTRIBUTION_TEXT='Arch Linux' \
               -DCMAKE_INSTALL_PREFIX=/usr \
               -DSYSCONF_INSTALL_DIR=/etc \
               -DHTML_INSTALL_DIR=/usr/share/doc/kde/html \
               -DKDE_DEFAULT_HOME='.kde4' \
               -DWITH_FAM=OFF \
               -DKAUTH_BACKEND=PolkitQt-1
       make
}

package() {
       cd $srcdir/build
       make DESTDIR=$pkgdir install

       # cert bundle seems to be hardcoded
       # link it to the one from ca-certificates
       rm -f $pkgdir/usr/share/apps/kssl/ca-bundle.crt
       ln -sf /etc/ssl/certs/ca-certificates.crt $pkgdir/usr/share/apps/kssl/ca-bundle.crt
}
